bigbluebutton-Github/bigbluebutton-apps/build.gradle

apply plugin: 'java'
apply plugin: 'war'
apply plugin: 'eclipse'
apply plugin: 'idea'

version = '0.9.0'
jar.enabled = true

def appName = 'bigbluebutton'

archivesBaseName = appName 

task resolveDeps(type: Copy) {
    into('lib')
    from configurations.default
    from configurations.default.allArtifacts.file
}

repositories {
  mavenCentral()
  mavenLocal()
}

dependencies {	 
  // Servlet
  providedCompile 'javax.servlet:servlet-api:2.5@jar'

  // Mina
  providedCompile 'org.apache.mina:mina-core:2.0.17@jar'
  providedCompile 'org.apache.mina:mina-integration-beans:2.0.17@jar'
  providedCompile 'org.apache.mina:mina-integration-jmx:2.0.17@jar'

  // Spring 
  providedCompile 'org.springframework:spring-web:4.3.12.RELEASE@jar' 
  providedCompile  'org.springframework:spring-beans:4.3.12.RELEASE@jar'
  providedCompile 'org.springframework:spring-context:4.3.12.RELEASE@jar'
  providedCompile 'org.springframework:spring-core:4.3.13.RELEASE@jar'

  // Red5
  providedCompile 'org.red5:red5-server:1.0.10-M5@jar'
  providedCompile 'org.red5:red5-server-common:1.0.10-M5@jar'
  
  // Logging
  providedCompile 'ch.qos.logback:logback-core:1.2.3@jar'
  providedCompile 'ch.qos.logback:logback-classic:1.2.3@jar'
  providedCompile 'org.slf4j:log4j-over-slf4j:1.7.25@jar' 
  providedCompile 'org.slf4j:jcl-over-slf4j:1.7.25@jar'
  providedCompile 'org.slf4j:jul-to-slf4j:1.7.25@jar'
  providedCompile 'org.slf4j:slf4j-api:1.7.25@jar'
  	
  // Needed for the JVM shutdown hook but needs to be put into red5/lib dir.
  // Otherwise we get exception on aop utils class not found.
  providedCompile 'org.springframework:spring-aop:4.3.12.RELEASE@jar'
  compile 'aopalliance:aopalliance:1.0@jar'
	     
  // Testing
  compile 'org.easymock:easymock:2.4@jar'
  
  //redis
  compile "redis.clients:jedis:2.7.2"
  compile 'org.apache.commons:commons-pool2:2.3'
 
   compile 'com.google.code.gson:gson:2.5'
   providedCompile 'org.apache.commons:commons-lang3:3.7'

  compile 'org.bigbluebutton:bbb-common-message_2.12:0.0.19-SNAPSHOT'
  compile 'org.bigbluebutton:bbb-apps-common_2.12:0.0.1-SNAPSHOT'
}

test {
  useTestNG() 
}

war.doLast {
  ant.unzip(src: war.archivePath, dest: "$buildDir/$appName")
}


task deploy() << {
  def red5AppsDir = '/usr/share/red5/webapps'
  def bbbDir = new File("${red5AppsDir}/$appName")
  ant.delete(dir: bbbDir)
  ant.mkdir(dir: bbbDir)
  ant.copy(todir: bbbDir) {
    fileset(dir: "$buildDir/$appName")
  }
}